Example: Creating a basic application

1. In the Flash authoring tool, select File > New.
2. In the New Document dialog box, select ActionScript file, and click OK.

   A new ActionScript editing window is displayed.

3. Select File > Save. Select a folder to contain your application, name the ActionScript file Greeter.as, and then click OK.

   Continue with Adding code to the Greeter class.

1. Type the following code into the new file:

   package 
   {
       public class Greeter 
       {
           public function sayHello():String 
           {
               var greeting:String;
               greeting = "Hello World!";
               return greeting;
           }
       }
   }
   

   The Greeter class includes a single sayHello() method, which returns a string that says "Hello" to the user name that is given.

2. Select File > Save to save this ActionScript file.

The Greeter class is now ready to be used in a Flash or Flex application.

1. Select File > New.
2. In the New Document dialog box, select Flash Document, and click OK.

   A new Flash window is displayed.

3. Select File > Save. Select the same folder that contains the Greeter.as class file, name the Flash document HelloWorld.fla, and click OK.
4. In the Flash Tools palette, select the Text tool, and drag across the Stage to define a new text field, approximately 300 pixels wide and 100 pixels high.
5. In the Properties window, with the text field still selected on the Stage, type mainText as the instance name of the text field.
6. Click the first frame of the main timeline.
7. In the Actions panel, type the following script:

   var myGreeter:Greeter = new Greeter();
   mainText.text = myGreeter.sayHello("Bob");
   

8. Save the file.

Continue with Publishing and testing your ActionScript application.

1. Publish your application and watch for compilation errors. In the Flash authoring tool, select Control > Test Movie to compile your ActionScript code and run the HelloWorld application.
2. If any errors or warnings are displayed in the Output window when you test your application, fix the causes of these errors in the HelloWorld.fla or HelloWorld.as files, and then try testing the application again.
3. If there are no compilation errors, you will see a Flash Player window showing the Hello World application. The "Hello, Bob" text is displayed.

You have just created a simple but complete object-oriented application that uses ActionScript 3.0. Continue with Enhancing the HelloWorld application.

1. Open the Greeter.as file.
2. Change the contents of the file to the following (new and changed lines are shown in boldface):

   package
   {
       public class Greeter
       {
           /**
            * Defines the names that should receive a proper greeting.
            */
           public static var validNames:Array = ["Sammy", "Frank", "Dean"];
   
           /**
            * Builds a greeting string using the given name.
            */
           public function sayHello(userName:String = ""):String 
           {
               var greeting:String;
               if (userName == "") 
               {
                   greeting = "Hello. Please type your user name, and then press the Enter key.";
               } 
               else if (validName(userName)) 
               {
                   greeting = "Hello, " + userName + ".";
               } 
               else 
               {
                   greeting = "Sorry, " + userName + ", you are not on the list.";
               }
               return greeting;
           }
           
           /**
            * Checks whether a name is in the validNames list.
            */
           public static function validName(inputName:String = ""):Boolean 
           {
               if (validNames.indexOf(inputName) > -1) 
               {
                   return true;
               } 
               else 
               {
                   return false;
               }
           }
       }
   }
   

1. Open the HelloWorld.fla file.
2. Modify the script in Frame 1 so that an empty string ("") is passed to the Greeter class's sayHello() method:

   var myGreeter:Greeter = new Greeter();
   mainText.text = myGreeter.sayHello("");
   

3. Select the Text tool in the Tools palette, and then create two new text fields on the Stage, side-by-side and directly under the existing mainText text field.
4. In the first new text field, type the text User Name: to serve as a label.
5. Select the other new text field, and in the Property inspector, select InputText as the type of text field. Type textIn as the instance name.
6. Click the first frame of the main timeline.
7. In the Actions panel, add the following lines to the end of the existing script:

   mainText.border = true;
   textIn.border = true;
   
   textIn.addEventListener(KeyboardEvent.KEY_UP, keyPressed);
   
   function keyPressed(event:Event):void
   {
       if (event.keyCode == Keyboard.ENTER)
       {
           mainText.text = myGreeter.sayHello(textIn.text);
       }
   }
   

   The new code adds the following functionality:

   • The first two lines simply define borders for two text fields.
   • An input text field, such as the textIn field, has a set of events that it can dispatch. The addEventListener() method lets you define a function that runs when a type of event occurs. In this case, that event is the pressing of the Enter key on the keyboard.
   • The keyPressed() custom function calls the sayHello() method of the myGreeter object, passing the text from the textIn text field as a parameter. That method returns a string greeting based on the value passed in. The returned string is then assigned to the text property of the mainText text field.

   The complete script for Frame 1 is the following:

   mainText.border = true;
   textIn.border = true;
   
   var myGreeter:Greeter = new Greeter();
   mainText.text = myGreeter.sayHello("");
   
   textIn.addEventListener(KeyboardEvent.KEY_UP, keyPressed);
   
   function keyPressed(event:Event):void
   {
       if (event.keyCode == Keyboard.ENTER)
       {
           mainText.text = myGreeter.sayHello(textIn.text);
       }
   }
   

8. Save the file.
9. Select Control > Test Movie to run the application.

   When you run the application, you will be prompted to enter a user name. If it is valid (Sammy, Frank, or Dean), the application displays the "hello" confirmation message.