// Copyright (C) 1997-2004 Alias Systems Corp.
// 
// The information in this file is provided for the exclusive use of the
// licensees of Alias.  Such users have the right to use, modify,
// and incorporate this code into other products for purposes authorized
// by the Alias license agreement, without fee.
// 
// ALIAS DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
// INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
// EVENT SHALL ALIAS BE LIABLE FOR ANY SPECIAL, INDIRECT OR
// CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
// DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
// TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
// PERFORMANCE OF THIS SOFTWARE.

// 
// licensees of Alias Systems.  Such users have the right to use, modify,
// by the Alias Systems license agreement, without fee.
// 
// ALIAS SYSTEMS DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
// EVENT SHALL ALIAS BE LIABLE FOR ANY SPECIAL, INDIRECT OR

proc setOptionVars(int $forceFactorySettings)
{
	if( $forceFactorySettings || !`optionVar -exists GB_HostName`){
		optionVar -stringValue GB_HostName "localhost";
	}

	// GB Port Number
	if( $forceFactorySettings || !`optionVar -exists GB_ServerPortNumber`){
		optionVar -intValue GB_ServerPortNumber 63419;
	}
}

proc cancelGBPrefs()
{
	deleteUI gbClientPrefsWindow;
}

proc resetDefaults( )
{
	setOptionVars(1);
	textFieldGrp -e -text `optionVar -q GB_HostName` gbHostName;
	intFieldGrp -e -v1 `optionVar -q GB_ServerPortNumber` gbPortNumber;
}

proc applyGBPrefs( )
{
	optionVar -intValue GB_ServerPortNumber `intFieldGrp -q -v1 gbPortNumber`;
	optionVar -stringValue GB_HostName `textFieldGrp -q -text gbHostName`;

	cancelGBPrefs();
}

global proc showGBClientPrefs()
{

	if (!`window -exists gbClientPrefsWindow`) {
		// Make sure the defaults exist.
		setOptionVars(0);

		// Build the window.
		window -title "Greenbox Client Preferences" gbClientPrefsWindow;
		setUITemplate -pushTemplate DefaultTemplate;
		tabLayout -scr true -tv false;
		string $parent = `columnLayout -adjustableColumn 1`;
		textFieldGrp -l "Host Name" gbHostName;
		intFieldGrp -l "Port Number" gbPortNumber;

		formLayout gbButtons;

		button -label "Apply And Close"
			   -command applyGBPrefs
			   gbApplyButton;

		button -label "Defaults"
			   -command resetDefaults
			   gbDefaultButton;

		button -label "Close"
			   -command cancelGBPrefs
			   gbCancelButton;

		formLayout -e
			-attachForm		gbApplyButton	"bottom"	5
			-attachForm		gbApplyButton	"left"		5
			-attachPosition	gbApplyButton	"right"		5	33

			-attachForm		gbDefaultButton			"bottom"	5
			-attachControl	gbDefaultButton			"left"		5	gbApplyButton
			-attachPosition	gbDefaultButton			"right"		5	66

			-attachForm		gbCancelButton			"bottom"	5
			-attachControl	gbCancelButton			"left"		5	gbDefaultButton
			-attachForm		gbCancelButton			"right"		5
			gbButtons;


		setUITemplate -popTemplate;

		// Set the default values
		textFieldGrp -e -text `optionVar -q GB_HostName` gbHostName;
		intFieldGrp -e -v1 `optionVar -q GB_ServerPortNumber` gbPortNumber;

		showWindow;
	}
}