ECHO.
ECHO ------------------------[Windows XP - Profile Settings]------------------------

ECHO.
ECHO Executing file "Windows XP Profile Settings.reg"...
START "" /WAIT REGEDIT /s "Registry\Windows XP - Profile Settings.reg"

IF NOT EXIST "%UserProfile%\Start Menu\Programs\Windows Media Player.lnk" GOTO SKIP
ECHO.
ECHO Creating Windows Media Player Shortcut on the Desktop and Quick Launch...
START "" /WAIT "..\Scripts\WMP Shortcuts Creator.vbs"
:SKIP

ECHO.
ECHO Creating IExpress Shortcut in "Start Menu -> All Programs -> Accessories"...
START "" /WAIT "..\Scripts\IExpress Shortcut Creator.vbs"

ECHO.
ECHO Deleting Remote Assistance Shortcut in "Start Menu -> All Programs"...
DEL "%UserProfile%\Start Menu\Programs\Remote Assistance.lnk" 2> NUL

ECHO.
ECHO Deleting Default Internet Explorer Feed Links...
RMDIR /S /Q "%UserProfile%\Local Settings\Application Data\Microsoft\Feeds\Microsoft Feeds~" 2> NUL

ECHO.
ECHO Deleting Default Windows XP Favorite URL Links...
DEL "%UserProfile%\Favorites\Links\Web Slice Gallery.url" 2> NUL
RMDIR /S /Q "%UserProfile%\Favorites\Microsoft Websites" 2> NUL

ECHO.
ECHO Creating New Windows XP Favorite URL Links...
CALL "Various\Windows XP - Favorite URL Links.cmd" 1> NUL

IF EXIST "%UserProfile%\My Documents\My Videos\Desktop.ini" GOTO SKIP
ECHO.
ECHO Creating Default "My Videos" folder in the "My Documents" folder...
MKDIR "%UserProfile%\My Documents\My Videos"
ATTRIB +S "%UserProfile%\My Documents\My Videos"
SET MVF="%UserProfile%\My Documents\My Videos\Desktop.ini"
ECHO [DeleteOnCopy]> %MVF%
ECHO Owner=%Username%>> %MVF%
ECHO Personalized=14>> %MVF%
ECHO PersonalizedName=My Videos>> %MVF%
ECHO [.ShellClassInfo]>> %MVF%
ECHO InfoTip=@Shell32.dll,-12690>> %MVF%
ECHO IconFile=%SystemRoot%\system32\SHELL32.dll>> %MVF%
ECHO IconIndex=-238>> %MVF%
ATTRIB +A +S +H "%UserProfile%\My Documents\My Videos\Desktop.ini"
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "My Video" /t REG_SZ /d "%UserProfile%\My Documents\My Videos" /f 1> NUL
REG ADD "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v "CommonVideo" /t REG_SZ /d "%AllUsersProfile%\Documents\My Videos" /f > NUL 2>&1
:SKIP

IF NOT EXIST "%SystemRoot%\Resources\Themes\Royale Remixed v1.47.theme" GOTO SKIP
ECHO.
ECHO Setting New Windows XP Theme...
START "" /WAIT "..\Scripts\Set Theme.vbs" "%SystemRoot%\Resources\Themes\Royale Remixed v1.47.theme"
ping -n 3 localhost 1> NUL
:SKIP