@echo off

if not "%ALIAS_TRANSLATION_SERVICE_LOCATION%"=="" goto setup

if not "%GREENBOX_HOME%"=="" goto setvar
	echo "Please set ALIAS_TRANSLATION_SERVICE_LOCATION."
	rem We don't want to return an exit status other than 0. To do
	rem so causes problems for the uninstaller.
	exit 0

:setvar

set ALIAS_TRANSLATION_SERVICE_LOCATION=%GREENBOX_HOME%

:setup

rem Slurp the command line arguments. This loop allows for an unlimited number
rem of arguments (up to the command line limit, anyway).
set GREENBOX_CMD_LINE_ARGS=%1
if ""%1""=="""" goto doneStart
shift
:setupArgs
if ""%1""=="""" goto doneStart
set GREENBOX_CMD_LINE_ARGS=%GREENBOX_CMD_LINE_ARGS% %1
shift
goto setupArgs

:doneStart

set GREENBOX_LIB=%ALIAS_TRANSLATION_SERVICE_LOCATION%\lib

set LOCALCLASSPATH=%GREENBOX_LIB%\greenbox.jar
set LOCALCLASSPATH=%LOCALCLASSPATH%;%GREENBOX_LIB%\jdom.jar
set LOCALCLASSPATH=%LOCALCLASSPATH%;%GREENBOX_LIB%\saxpath.jar
set LOCALCLASSPATH=%LOCALCLASSPATH%;%GREENBOX_LIB%\jaxen-core.jar
set LOCALCLASSPATH=%LOCALCLASSPATH%;%GREENBOX_LIB%\jaxen-jdom.jar
set LOCALCLASSPATH=%LOCALCLASSPATH%;%GREENBOX_LIB%\xerces.jar
set LOCALCLASSPATH=%LOCALCLASSPATH%;%GREENBOX_LIB%\xalan.jar
set LOCALCLASSPATH=%LOCALCLASSPATH%;%GREENBOX_LIB%\xml-apis.jar

set OLD_JAVA_HOME=%JAVA_HOME%
set JAVA_HOME=%ALIAS_TRANSLATION_SERVICE_LOCATION%\java

rem set greenbox properties. Note that the trailing '.' is IMPORTANT!
rem If the env. var ends in a single '\' this avoids escaping the 
rem quote in the command line. It is silently eaten if there is no
rem final '\' in the env. var.
set GB_PROP="-Dgreenbox.home=%ALIAS_TRANSLATION_SERVICE_LOCATION%."

"%JAVA_HOME%\bin\java" -classpath "%LOCALCLASSPATH%" %GB_PROP% com.alias.greenbox.Shutdown %GREENBOX_CMD_LINE_ARGS%

@rem Reset so as not to confuse the invoking shell.
set JAVA_HOME=%OLD_JAVA_HOME%