Example: Creating a complex interface

The following example shows several ways to define and implement interfaces. In this tutorial you learn how to create a simple interface file and how to write a class that implements multiple interfaces, as well as how to have interfaces extend other interfaces to create more complex data structures.

Create a new ActionScript document and save it as InterfaceA.as.
Create a new folder called complexInterface and save InterfaceA.as to this directory.
You save all of the files you create for this tutorial in this directory.

In Interface.as, type the following ActionScript code into the Script window:

// filename: InterfaceA.as
interface InterfaceA {
    public function k():Number;
    public function n(z:Number):Number;
}

Save the ActionScript document and then create a new ActionScript document named ClassB.as and save it in the complexInterface directory.
ClassB.as implements the InterfaceA interface you created previously.

In ClassB.as, type the following ActionScript code into the Script window:

// filename: ClassB.as
class ClassB implements InterfaceA {
    public function k():Number {
        return 25;
    }
    public function n(z:Number):Number {
        return (z + 5);
    }
}

Save your changes to the ClassB.as document and then create a new Flash document and save it as classbTest.fla in the complexInterface directory.
This class file tests the ClassB class you created previously.

In classbTest.fla, type the following ActionScript code on Frame 1 of the Timeline:

// filename: classbTest.fla
import ClassB;
var myB:ClassB = new ClassB();
trace(myB.k()); // 25
trace(myB.n(7)); // 12

Save your changes to the Flash document, and then select Control >Test Movie to test the Flash document.
The Output panel displays two numbers, 25 and 12, which are the results of the k() and n() methods in the ClassB class.
Create a new ActionScript file and save it as ClassC.as in the complexInterface directory.
This class file implements the InterfaceA interface that you created in step 1.
In ClassC.as, type the following ActionScript code into the Script window:
```
// filename: ClassC.as
class ClassC implements InterfaceA {
    public function k():Number {
        return 25;
    }
    // **Error** The class must also implement method 'n' from interface 'InterfaceA'.
}
```
If you click the Check Syntax button for the ClassC class file, Flash displays an error message in the Output panel that says the current class must implement the n() method defined in the InterfaceA interface. When you create classes that implement an interface, it is important that you define methods for each entry in the interface.
Create a new ActionScript document and save it as InterfaceB.as in the complexInterface directory.

In InterfaceB.as, type the following ActionScript code into the Script window:

// filename: InterfaceB.as
interface InterfaceB {
    public function o():Void;
}

Save your changes to the InterfaceB.as document, and then create a new ActionScript document and save it in the complexInterface directory as ClassD.as.
This class implements both the InterfaceA interface and the InterfaceB interface you created in earlier steps. The ClassD class must include method implementations for each of the methods listed in each of the interface files.

In ClassD.as, type the following ActionScript code into the Script window:

// filename: ClassD.as
class ClassD implements InterfaceA, InterfaceB {
    public function k():Number {
        return 15;
    }
    public function n(z:Number):Number {
        return (z * z);
    }
    public function o():Void {
        trace("o");
    }
}

Save your changes to the ClassD.as file, and then create a new Flash document and save it as classdTest.fla.
This Flash document tests the ClassD class that you created previously.

In classdTest.fla, add the following ActionScript code on Frame 1 of the Timeline:

// filename: classdTest.fla
import ClassD;
var myD:ClassD = new ClassD();
trace(myD.k()); // 15
trace(myD.n(7)); // 49
myD.o(); // o

Save your changes to the classdTest.fla file and then select Control > Test Movie to test the file.
The values 15 and 49 and the letter o should be displayed in the Output panel. These values are the results of the ClassD.k() method, ClassD.n(), and ClassD.o() methods, respectively.
Create a new ActionScript document and save it as InterfaceC.as.
This interface extends the InterfaceA interface you created earlier, and it adds a new method definition.

In InterfaceC.as, type the following ActionScript code into the Script window:

// filename: InterfaceC.as
interface InterfaceC extends InterfaceA {
    public function p():Void;
}

Save your changes to the ActionScript file and then create a new ActionScript file and save it as ClassE.as in the complexInterface directory.
This class implements two interfaces, InterfaceB and InterfaceC.

In ClassE.as, type the following ActionScript code into the Script window:

// filename: ClassE.as
class ClassE implements InterfaceB, InterfaceC {
    public function k():Number {
        return 15;
    }
    public function n(z:Number):Number {
        return (z + 5);
    }
    public function o():Void {
        trace("o");
    }
    public function p():Void {
        trace("p");
    }
}

Save your changes to the ActionScript document, and then create a new Flash document and save it as classeTest.fla in the complexInterface directory.

In classeTest.fla, type the following ActionScript code on Frame 1 of the Timeline:

// filename: classeTest.fla
import ClassE;
var myE:ClassE = new ClassE();
trace(myE.k()); // 15
trace(myE.n(7)); // 12
myE.o(); // o
myE.p(); // p

Save the Flash document, and then select Control > Test Movie to test the SWF file.
The values 15, 12, o, and p display in the Output panel. These values are the values that return from the ClassE.k(), ClassE.n(), ClassE.o(), and ClassE.p() methods. Since the ClassE class implemented both the InterfaceB and InterfaceC interfaces, each method from the two interface files must be defined. Although the InterfaceB and InterfaceC interfaces only define the o() and p() methods, InterfaceC extends InterfaceA. This means that all of its defined methods, k() and n(), must also be implemented.

Example: Creating a complex interface

To create a complex interface: