ActionScript 2.0 Components Language Reference
Window component > Window.mouseDownOutside

Window.mouseDownOutside

Availability

Flash Player 6 (6.0.79.0).

Edition

Flash MX 2004.

Usage

Usage 1:

var listenerObject:Object = new Object();
listenerObject.mouseDownOutside = function(eventObject:Object) {
    // ...
};
windowInstance.addEventListener("mouseDownOutside", listenerObject);

Usage 2:

on (mouseDownOutside) {
    // ...
}

Description

Event; broadcast to all registered listeners when the mouse is clicked (released) outside the modal window. This event is rarely used, but you can use it to dismiss a window if the user tries to interact with something outside it.

The first usage example uses a dispatcher/listener event model. A component instance (windowInstance) dispatches an event (in this case, mouseDownOutside) and the event is handled by a function, also called a handler, on a listener object (listenerObject) that you create. You define a method with the same name as the event on the listener object; the method is called when the event is triggered. When the event is triggered, it automatically passes an event object (eventObject) to the listener object method. The event object has properties that contain information about the event. You can use these properties to write code that handles the event. Finally, you call the EventDispatcher.addEventListener() method on the component instance that broadcasts the event to register the listener with the instance. When the instance dispatches the event, the listener is called.

For more information, see EventDispatcher class.

The second usage example uses an on() handler and must be attached directly to a Window instance. The keyword this, used inside an on() handler attached to a component, refers to the component instance. For example, the following code, attached to the Window instance myWindowComponent, sends "_level0.myWindowComponent" to the Output panel:

on (mouseDownOutside) {
    trace(this);
}

Example

The following example creates a window instance and defines a mouseDownOutside handler that displays a message if the user clicks outside the window. You drag a Window component from the Components panel to the current document's library, and then add the following code to Frame 1:

/**
 Requires:
  - Window component in library
*/

import mx.managers.PopUpManager;
import mx.containers.Window;

System.security.allowDomain("http://www.flash-mx.com");

// Create window. 
var my_win:MovieClip = PopUpManager.createPopUp(this, Window, true, undefined, true);

// Create a listener object.
var winListener:Object = new Object();
winListener.mouseDownOutside = function(evt_obj:Object)
{
    trace("mouseDownOutside event triggered.");
}
// Add listener.
my_win.addEventListener("mouseDownOutside", winListener);

See also

EventDispatcher.addEventListener()

View comments on LiveDocs