ActionScript 2.0 Components Language Reference
TextArea component > TextArea.change

TextArea.change

Availability

Flash Player 6 (6.0.79.0).

Edition

Flash MX 2004.

Usage

Usage 1:

var listenerObject:Object = new Object();
listenerObject.change = function(eventObject:Object) {
    // ...
};
textAreaInstance.addEventListener("change", listenerObject);

Usage 2:

on (change) {
    // ...
}

Description

Event; notifies listeners that text has changed. This event is broadcast after the text has changed. This event cannot be used to prevent certain characters from being added to the component's text area; for this purpose, use TextArea.restrict.

The first usage example uses a dispatcher/listener event model. A component instance (textAreaInstance) dispatches an event (in this case, change) and the event is handled by a function, also called a handler, on a listener object (listenerObject) that you create. You define a method with the same name as the event on the listener object; the method is called when the event is triggered. When the event is triggered, it automatically passes an event object (eventObject) to the listener object method. Each event object has properties that contain information about the event. You can use these properties to write code that handles the event. Finally, you call the EventDispatcher.addEventListener() method on the component instance that broadcasts the event to register the listener with the instance. When the instance dispatches the event, the listener is called.

For more information, see EventDispatcher class.

The second usage example uses an on() handler and must be attached directly to a TextArea instance. The keyword this, used inside an on() handler attached to a component, refers to the component instance. For example, the following code, attached to the instance myTextArea, sends "_level0.myTextArea" to the Output panel:

on (change) {
    trace(this);
}

Example

This example uses the dispatcher/listener event model to track the total of number of times the text area changes in a TextArea component named my_ta.

You must first add an instance of the TextArea component to the Stage and name it my_ta; then add the following code to Frame 1.

/**
 Requires:
  - TextArea instance on Stage (instance name: my_ta)
*/

var my_ta:mx.controls.TextArea;

// Create a Number variable to track the number of changes to the TextArea.
var changeCount_num:Number = 0;

// Define a listener object.
var taListener:Object = new Object();
// Define a function that is executed whenever the listener receives
// notification of a change in the TextArea component.
taListener.change = function(evt_obj:Object) {
 changeCount_num++;
 trace("Text has changed " + changeCount_num + " times now!");
 trace("It now contains: " + evt_obj.target.text);
 trace("");
};
// Register the listener object with the TextArea component instance.
my_ta.addEventListener("change", taListener);

See also

EventDispatcher.addEventListener()

View comments on LiveDocs