ActionScript 2.0 Components Language Reference
ScrollPane component > ScrollPane.scroll

ScrollPane.scroll

Availability

Flash Player 6 (6.0.79.0).

Edition

Flash MX 2004.

Usage

Usage 1:

var listenerObject:Object = new Object();
listenerObject.scroll = function(eventObject:Object):Void {
    // ...
};
scrollPaneInstance.addEventListener("scroll", listenerObject);

Usage 2:

on (scroll) {
    // ...
}

Event object

In addition to the standard event object properties, there are two additional properties defined for the scroll event: a type property whose value is "scroll", and a direction property whose value can be "vertical" or "horizontal".

In addition to the standard event object properties, there are two additional properties defined for the ProgressBar.progress event: current (the loaded value equals total), and total (the total value).

Description

Event; broadcast to all registered listeners when a user clicks the scroll bar buttons, scroll box (thumb), or scroll track. Unlike other events, the scroll event is broadcast when a user presses the mouse button on the scroll bar and continues broadcasting until the button is released.

The first usage example uses a dispatcher/listener event model. A component instance (scrollPaneInstance) dispatches an event (in this case, scroll) and the event is handled by a function, also called a handler, on a listener object (listenerObject) that you create. You define a method with the same name as the event on the listener object; the method is called when the event is triggered. When the event is triggered, it automatically passes an event object (eventObject) to the listener object method. Each event object has properties that contain information about the event. You can use these properties to write code that handles the event. Finally, you call the EventDispatcher.addEventListener() method on the component instance that broadcasts the event to register the listener with the instance. When the instance dispatches the event, the listener is called.

For more information, see EventDispatcher class.

The second usage example uses an on() handler and must be attached directly to a ScrollPane instance. The keyword this, used inside an on() handler attached to a component, refers to the component instance. For example, the following code, attached to the instance my_sp, sends "_level0.my_sp" to the Output panel:

on (scroll) {
    trace(this);
}

Example

This example creates a ScrollPane instance called my_sp, loads it with an image, and creates a listener for the scroll event. When a scroll event occurs, the example displays the horizontal (hPosition) and vertical (vPosition) scroll positions in the Output panel.

You first drag the ScrollPane component from the Components panel to the current document's library and then add the following code to Frame 1:

/**
 Requires:
  - ScrollPane component in library
*/

this.createClassObject(mx.containers.ScrollPane, "my_sp", 10);
my_sp.setSize(360, 280);

System.security.allowDomain("http://www.helpexamples.com");
my_sp.contentPath = "http://www.helpexamples.com/flash/images/image1.jpg";
// Scroll 100 pixels when clicking on horizontal bar.
my_sp.hPageScrollSize = 100;

// Create listener object.
var spListener:Object = new Object();
spListener.scroll = function(evt_obj:Object):Void {
   trace("hPosition = " + my_sp.hPosition + ", vPosition = " + my_sp.vPosition);
};
// Add listener.
my_sp.addEventListener("scroll", spListener);

See also

EventDispatcher.addEventListener()

View comments on LiveDocs