RadioButton.click

var listenerObject:Object = new Object();
listenerObject.click = function(eventObj:Object) {
    // ...
};
radioButtonGroup.addEventListener("click", listenerObject);

on (click) {
    // ...
}

Description

Event; broadcast to all registered listeners when the mouse is clicked (pressed and released) over the radio button or if the radio button is selected by means of the arrow keys. The event is also broadcast if the Spacebar or arrow keys are pressed when a radio button group has focus, but none of the radio buttons in the group are selected.

The first usage example uses a dispatcher/listener event model. A component instance (radioButtonInstance) dispatches an event (in this case, click) and the event is handled by a function, also called a handler, on a listener object (listenerObject) that you create. You define a method with the same name as the event on the listener object; the method is called when the event is triggered. When the event is triggered, it automatically passes an event object (eventObject) to the listener object method. The event object has properties that contain information about the event. You can use these properties to write code that handles the event. Finally, you call the EventDispatcher.addEventListener() method on the component instance that broadcasts the event to register the listener with the instance. When the instance dispatches the event, the listener is called.

The second usage example uses an on() handler and must be attached directly to a RadioButton instance. The keyword this, used inside an on() handler attached to a component, refers to the component instance. For example, the following code, attached to the radio button myRadioButton, sends "_level0.myRadioButton" to the Output panel:

on (click) {
    trace(this);
}

Example

The following example creates three radio buttons, positions them on the Stage, and creates a listener for the click event. When a user clicks one of the three radio buttons, the listener displays the instance name of the selected radio button.

You first drag a RadioButton component from the Components panel to the current document's library, and then add the following code to Frame 1 of the main timeline:

/**
 Requires:
  - RadioButton component in library
*/

import mx.controls.RadioButton;

this.createClassObject(RadioButton, "first_rb", 10, {label:"first", groupName:"radioGroup"});
this.createClassObject(RadioButton, "second_rb", 20, {label:"second", groupName:"radioGroup"});
this.createClassObject(RadioButton, "third_rb", 30, {label:"third", groupName:"radioGroup"});

// Position RadioButtons on Stage.
second_rb.move(0, first_rb.y + first_rb.height);
third_rb.move(0, second_rb.y + second_rb.height);

// Create listener object.
var rbListener:Object = new Object(); 
rbListener.click = function(evt_obj:Object){
   trace("The selected radio instance is " + evt_obj.target.selection);
} 
// Add listener.
radioGroup.addEventListener("click", rbListener);

RadioButton.click

Availability

Edition

Usage

Description

Example