ActionScript 2.0 Components Language Reference
ProgressBar component > ProgressBar.complete

ProgressBar.complete

Availability

Flash Player 6 (6.0.79.0).

Edition

Flash MX 2004.

Usage

Usage 1:

var listenerObject:Object = new Object();
listenerObject.complete = function(eventObject:Object) {
    // ...
};
progressBarInstance.addEventListener("complete", listenerObject);

Usage 2:

on (complete) {
    // ...
}

Event object

In addition to the standard event object properties, there are two additional properties defined for the ProgressBar.complete event: current (the loaded value equals total), and total (the total value).

Description

Event; broadcast to all registered listeners when the loading progress has completed.

The first usage example uses a dispatcher/listener event model. A component instance (progressBarInstance) dispatches an event (in this case, complete) and the event is handled by a function, also called a handler, on a listener object (listenerObject) that you create. You define a method with the same name as the event on the listener object; the method is called when the event is triggered. When the event is triggered, it automatically passes an event object (eventObject) to the listener object method. Each event object has properties that contain information about the event. You can use these properties to write code that handles the event. Finally, you call the EventDispatcher.addEventListener() method on the component instance that broadcasts the event to register the listener with the instance. When the instance dispatches the event, the listener is called.

For more information, see EventDispatcher class.

The second usage example uses an on() handler and must be attached directly to a ProgressBar instance. The keyword this, used inside an on() handler attached to a component, refers to the component instance. For example, the following code, attached to the instance progressBarInstance, sends "_level0.progressBarInstance" to the Output panel:

on (complete) {
    trace(this);
}

Example

This example creates a Loader component, a ProgressBar (my_pb) for it, and a listener that makes the progress bar invisible when the complete event occurs. The example loads an image into the loader my_ldr.

You must first drag a Loader component and a ProgressBar component from the Components panel to the current document's library; then add the following code to Frame 1 of the main timeline:

/**
 Requires:
  - ProgressBar component in library
  - Loader component in library
*/

System.security.allowDomain("http://www.helpexamples.com");

this.createClassObject(mx.controls.Loader, "my_ldr", 10, {autoLoad:false});
this.createClassObject(mx.controls.ProgressBar, "my_pb", 20, {indeterminate:true, source:my_ldr, mode:"polled"});

// Create Listener Object
var pbListener:Object = new Object();
pbListener.complete = function(evt_obj:Object) {
 my_pb.visible = false;
};
// Add Listener
my_pb.addEventListener("complete", pbListener);

my_ldr.load("http://www.helpexamples.com/flash/images/image2.jpg");

See also

EventDispatcher.addEventListener()

View comments on LiveDocs