NumericStepper.change

Availability

Flash Player 6 (6.0.79.0).

Edition

Flash MX 2004.

Usage

Usage 1:

var listenerObject:Object = new Object();
listenerObject.change = function(eventObject:Object) {
    //...
};
numericStepperInstance.addEventListener("change", listenerObject);

Usage 2:

on (change) {
    // ...
}

Description

Event; broadcast to all registered listeners when the value of the stepper is changed.

A component instance (stepperInstance) dispatches an event (in this case, change) and the event is handled by a function, also called a handler, on a listener object (listenerObject) that you create. You define a method with the same name as the event on the listener object; the method is called when the event is triggered. When the event is triggered, it automatically passes an event object (eventObject) to the listener object method. Each event object has properties that contain information about the event. You can use these properties to write code that handles the event. Finally, you call the EventDispatcher.addEventListener() method on the component instance that broadcasts the event to register the listener with the instance. When the instance dispatches the event, the listener is called.

For more information, see EventDispatcher class.

Example

The following example creates a listener for a change event on the numeric stepper called my_nstep. When you change the value in the numeric stepper, the listener displays the value (value property) in the Output panel.

Drag an instance of the NumericStepper component onto the Stage, and enter the instance name my_nstep in the Property inspector. Add the following code to Frame 1 of the timeline:

/**
 Requires:
  - NumericStepper component on Stage (instance name: my_nstep)
*/

var my_nstep:mx.controls.NumericStepper;

// Create listener object.
var nstepListener:Object = new Object();
nstepListener.change = function(evt_obj:Object){
 // evt_obj.target is the component that generated the change event,
 // i.e., the numeric stepper.
 trace("Value changed to " + evt_obj.target.value);
}
// Add listener.
my_nstep.addEventListener("change", nstepListener);

View comments on LiveDocs