ActionScript 2.0 Components Language Reference
Menu component > Menu.rollOut

Menu.rollOut

Availability

Flash Player 6 (6.0.79.0).

Edition

Flash MX Professional 2004.

Usage

Usage 1:

var listenerObject:Object = new Object();
listenerObject.rollOut = function(eventObject:Object) {
    // Insert your code here.
};
menuInstance.addEventListener("rollOut", listenerObject);

Usage 2:

on (rollOut) {
    // Insert your code here. 
}

Description

Event; broadcast to all registered listeners when the pointer rolls off a menu item.

Components use a dispatcher-listener event model. When a Menu component broadcasts a rollOut event, the event is handled by a function (also called a handler) that is attached to a listener object (listenerObject) that you create. You call the addEventListener() method and pass it the name of the handler as a parameter.

When the event is triggered, it automatically passes an event object (eventObject) to the handler. Each event object has properties that contain information about the event. You can use these properties to write code that handles the event. The Menu.rollOut event's event object has one additional property: menuItem, which is a reference to the menu item (XML node) that the pointer rolled off.

For more information, see EventDispatcher class.

Example

The following example creates a menu with two items and a listener for a rollOut event. When the rollOut event is broadcast, a trace() function in the event handler, menuListener, displays the name of the menu item for which the event occurred.

You first drag a Menu component to the library and then add the following code to Frame 1:

/**
 Requires:
  - Menu component in library
*/

import mx.controls.Menu;

// Create an XML object to act as a factory.
var my_xml:XML = new XML();

// The item created next does not appear in the menu.
// The createMenu() method call (below) expects to
// receive a root element whose children will become
// the items. This is just a simple way to create that
// root element and give it a convenient name.
var menuDP_obj:Object = my_xml.addMenuItem("XXXXX");

// Add the menu items.
menuDP_obj.addMenuItem({label:"1st Item"});
menuDP_obj.addMenuItem({label:"2nd Item"});

// Create the Menu object.
var my_menu:Menu = Menu.createMenu(this, menuDP_obj);

// Show and position the menus.
my_menu.show(100, 20);

// Create listener object.
var menuListener:Object = new Object();
menuListener.rollOut = function(evt_obj:Object) {
 trace("Menu rollOut: " + evt_obj.menuItem.attributes.label);
};

// Add listener.
my_menu.addEventListener("rollOut", menuListener);

View comments on LiveDocs