ActionScript 2.0 Components Language Reference
List component > List.scroll

List.scroll

Availability

Flash Player 6 (6.0.79.0).

Edition

Flash MX 2004.

Usage

Usage 1:

var listenerObject:Object = new Object();
listenerObject.scroll = function(eventObject:Object) {
    // Your code here.
};
listInstance.addEventListener("scroll", listenerObject);

Usage 2:

on (scroll) {
    // Your code here.
}

Event object

Along with the standard event object properties, the scroll event has one additional property, direction. It is a string with two possible values, "horizontal" or "vertical". For a ComboBox scroll event, the value is always "vertical".

Description

Event; broadcast to all registered listeners when a list is scrolled.

The first usage example uses a dispatcher/listener event model. A component instance (listInstance) dispatches an event (in this case, scroll) and the event is handled by a function, also called a handler, on a listener object (listenerObject) that you create. You define a method with the same name as the event on the listener object; the method is called when the event is triggered. When the event is triggered, it automatically passes an event object (eventObject) to the listener object method. Each event object has properties that contain information about the event. You can use these properties to write code that handles the event. Finally, you call the EventDispatcher.addEventListener() method on the component instance that broadcasts the event to register the listener with the instance. When the instance dispatches the event, the listener is called.

For more information, see EventDispatcher class (API).

The second usage example uses an on() handler and must be attached directly to a List instance. The keyword this, used inside an on() handler attached to a component, refers to the component instance. For example, the following code, attached to the List instance my_list, sends "_level0.my_list" to the Output panel:

on (scroll) {
    trace(this);
}

Example

The following example sends the direction and position of the list every time the list items are scrolled:

var my_list:mx.controls.List;

my_list.rowCount = 2;
for (var i:Number = 0; i < 10; i++) {
    my_list.addItem({data:i, label:"Item #" + i});
}

var listListener:Object = new Object();
listListener.scroll = function(evt_obj:Object) {
    trace("list scrolled (direction:" + evt_obj.direction + ", position:" + evt_obj.position + ")");
};
my_list.addEventListener("scroll", listListener);

View comments on LiveDocs