import Weave.Controls
import Weave.Templates as T

Menu {
    id: actionMenu

    HeaderActionMenuItem {
        id: ascendItem
        text: qsTr("Sort by ASC")
        icon.name: "pin-row-top"
        T.TableLayout.visible: actionMenu.T.HeaderActions.sortingEnabled
                && actionMenu.T.HeaderActions.sortOrder !== T.TableLayout.Ascending
        onClicked: actionMenu.T.HeaderActions.sortOrder = T.TableLayout.Ascending
    }
    HeaderActionMenuItem {
        id: descendItem
        text: qsTr("Sort by DESC")
        icon.name: "pin-row-bottom"
        T.TableLayout.visible: actionMenu.T.HeaderActions.sortingEnabled
                && actionMenu.T.HeaderActions.sortOrder !== T.TableLayout.Descending
        onClicked: actionMenu.T.HeaderActions.sortOrder = T.TableLayout.Descending
    }
    HeaderActionMenuItem {
        id: unsortItem
        text: qsTr("Unsort")
        T.TableLayout.visible: actionMenu.T.HeaderActions.sortingEnabled
                && actionMenu.T.HeaderActions.sortOrder !== T.TableLayout.Unsorted
        onClicked: actionMenu.T.HeaderActions.sortOrder = T.TableLayout.Unsorted
    }
    MenuSeparator {
    }
    HeaderActionMenuItem {
        id: leftItem
        text: qsTr("Pin to left")
        icon.name: "pin"
        T.TableLayout.visible: actionMenu.T.HeaderActions.leftPinningEnabled
                && actionMenu.T.HeaderActions.pinnedPosition !== T.TableLayout.PinnedLeft
        onClicked: actionMenu.T.HeaderActions.pinnedPosition = T.TableLayout.PinnedLeft
    }
    HeaderActionMenuItem {
        id: rightItem
        text: qsTr("Pin to right")
        icon.name: "pin-right"
        T.TableLayout.visible: actionMenu.T.HeaderActions.rightPinningEnabled
                && actionMenu.T.HeaderActions.pinnedPosition !== T.TableLayout.PinnedRight
        onClicked: actionMenu.T.HeaderActions.pinnedPosition = T.TableLayout.PinnedRight
    }
    HeaderActionMenuItem {
        id: unpinItem
        text: qsTr("Unpin")
        T.TableLayout.visible:  (actionMenu.T.HeaderActions.leftPinningEnabled
                && actionMenu.T.HeaderActions.pinnedPosition === T.TableLayout.PinnedLeft)
                || (actionMenu.T.HeaderActions.rightPinningEnabled
                && actionMenu.T.HeaderActions.pinnedPosition === T.TableLayout.PinnedRight)
        onClicked: actionMenu.T.HeaderActions.pinnedPosition = T.TableLayout.ColumnNotPinned
    }
    MenuSeparator {
    }
    HeaderActionMenuItem {
        text: qsTr("Filter")
        icon.name: "filter"
        T.TableLayout.visible: actionMenu.T.HeaderActions.columnFilteringEnabled
        onClicked: actionMenu.T.HeaderActions.filterColumn()
    }
    MenuSeparator {
    }
    HeaderActionMenuItem {
        text: qsTr("Hide Column")
        icon.name: "hidden"
        T.TableLayout.visible: actionMenu.T.HeaderActions.columnHidingEnabled
        onClicked: actionMenu.T.HeaderActions.hideColumn()
    }
    HeaderActionMenuItem {
        text: qsTr("Manage Columns")
        T.TableLayout.visible: actionMenu.T.HeaderActions.columnHidingEnabled
        onClicked: actionMenu.T.HeaderActions.openManageColumnsMenu()
    }
}